GDI+ et ASP.Net : la génération d'images

Date de publication : 18/05/2005

Par Ronald VASSEUR (autres articles)
 

Introduction

1. Génération d'une image contenant du texte

1.1. Image sauvegardée sur le disque dur

Génération d'image vers le disque dur :
Sub generationImageVersDisque(ByVal monTexte As String)

        ' Instanciation d'un objet Bitmap qui va jouer, en quelque sorte, le rôle de conteneur.
        ' On passe au constructeur les dimensions en pixels que l'on souhaite (largeur, hauteur)
        Dim monBitmap As Bitmap = New Bitmap(700, 80)


        ' Création d'un objet Graphics qui va être notre surface de dessin, on l'associe
        ' à notre objet Bitmap grâce à la méthode FromImage
        Dim monGraphic As Graphics = Graphics.FromImage(monBitmap)


        ' Instanciation de deux objets Brush qui vont nous permettre, respectivement,
        ' de "peindre" le fond, puis de "dessiner" le texte par dessus. Nous leur
        ' passons la couleur que l'on souhaite leur donner
        Dim monPinceau As New SolidBrush(Color.Tomato)
        Dim monStylo As New SolidBrush(Color.Yellow)


        ' Ici nous nous créons un rectangle de la taille de notre surface de dessin avec
        ' l'objet Brush.
        monGraphic.FillRectangle(monPinceau, 0, 0, 700, 80)


        ' Objet Font qui contient la police et ses caractéristiques
        Dim maPolice As New Font("Arial", 35, FontStyle.Regular)


        ' Structure PointF qui est un ensemble de 2 coordonnées pour le début du texte
        ' sur la surface de dessin.
        Dim mesCoor As New PointF(5.0F, 5.0F)


        ' Rendu du texte : ici nous sommes en qualité optimale.
        ' Plus de détails sur le sujet dans la suite de ce tutoriel
        monGraphic.TextRenderingHint = Text.TextRenderingHint.ClearTypeGridFit


        ' "Ecriture" du texte sur la surface de dessin, en paramètres, on passe, 
        ' dans l'ordre, le texte, la police, le pinceau, et l'emplacement.
        monGraphic.DrawString(monTexte, maPolice, monStylo, mesCoor)


        ' Enregistrement à la racine de l'application le fichier généré
        monBitmap.Save(Server.MapPath("monImage.jpg"), ImageFormat.Jpeg)


        ' Ce code crée un lien sur votre page pour que vous puissiez vérifier le résultat,
        ' mais il n'est pas nécessaire pour la création de l'image elle-même.
        Response.Write("<a target=""_parent"" href=""monImage.jpg"">Votre image</a>")


    End Sub

Remarque : le compte ASP.Net doit avoir le droit d'écriture sur l'emplacement où va être stocké le fichier. En cas de droits insuffisants, une exception sera levée.

1.2. Transfert direct de l'image de la mémoire à la page ASPX

' Enregistrement à la racine de l'application le fichier généré
monBitmap.Save(Server.MapPath("monImage.jpg"), ImageFormat.Jpeg

Response.ContentType = "image/jpeg"
monBitmap.Save(Response.OutputStream, ImageFormat.Jpeg)

1.3. Le rendu des textes

monGraphic.TextRenderingHint = Text.TextRenderingHint.ClearTypeGridFit

2. Différents pinceaux proposés par GDI+

2.1. SolidBrush

2.2. Linear et Path Gradient Brush

2.3. HatchBrush

2.4. TextureBrush

3. Génération d'une image contenant un texte aléatoire

3.1. La méthode

Avertissement : après quelques tests, Random ne s'avère pas être totalement aléatoire... En effet, certaines chaînes reviennent tous les 20 à 30 essais, ce n'est pas un problème en soit, pour l'utilisation que l'on veut en faire, mais je tenais quand même à le signaler.

3.2. Le code commenté

Génération d'une image contenant un texte aléatoire
    Sub generationImageAleatoire(ByVal nombreCaracteres As Integer)

        ' Création du conteneur de notre image
        Dim monBitmap As Bitmap = New Bitmap(185, 50)
        Dim monGraphic As Graphics = Graphics.FromImage(monBitmap)


        ' Choix aléatoire de la couleur du fond. RVB limité à 200 pour que
        ' le fond ne soit pas trop clair (car écriture blanche)
        Dim nombreAleatoire As Random = New Random(DateTime.Now.Millisecond)
        Dim r, v, b As Integer
        r = nombreAleatoire.Next(0, 200)
        v = nombreAleatoire.Next(0, 200)
        b = nombreAleatoire.Next(0, 200)

        ' Coloration du fond
        Dim monPinceau As New SolidBrush(Color.FromArgb(r, v, b))
        monGraphic.FillRectangle(monPinceau, 0, 0, 185, 50)

        ' Création de la Font pour écrire le texte
        Dim maFont As Font = New Font("Arial", 25, FontStyle.Regular)

        ' Création du "stylo" qui va nous permettre d'écrire le texte
        Dim monStylo As New SolidBrush(Color.White)

        ' Structure PointF qui est un ensemble de 2 coordonnées pour le début du texte
        ' sur la surface de dessin.
        Dim mesCoor As New PointF(5.0F, 5.0F)


        ' Liste des caractères composant la chaîne aléatoire
        Dim liste() As String = {"A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", _
                                "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", _
                                "W", "X", "Y", "Z", "1", "2", "3", "4", "5", "6", "7", "8", "9"}

        ' Variable qui va contenir le texte
        Dim monTexte As StringBuilder = New StringBuilder

        ' Création aléatoire du texte
        Dim i As Integer = 0
        While i < nombreCaracteres
            monTexte = monTexte.Append(liste(nombreAleatoire.Next(0, 34)))
            i += 1
        End While

        ' Détermination du rendu du texte dans l'image
        monGraphic.TextRenderingHint = Text.TextRenderingHint.ClearTypeGridFit

        ' La chaîne est "dessinée" sur l'image
        monGraphic.DrawString(monTexte.ToString, maFont, monStylo, mesCoor)

        ' Affichage de l'image sur la page
        Response.ContentType = "image/jpeg"
        monBitmap.Save(Response.OutputStream, ImageFormat.Jpeg)

    End Sub

Conclusion

Ressources

 Les rendus de texte
 La classe Brush